% Branles from 'T Uitnement Kabinet
% source: GIFs at www.fourwinds.demon.nl/branles.htm
% ABC transcription by Jack Campin 2002
%
X:1
T:Petit Branle
S:http://www.fourwinds.demon.nl/branles.htm
Z:Jack Campin 2002
M:C|
L:1/8
K:D Dorian
f2e2 defg|a2g2 f2c2|f2e2 defg|a2g2 f4 :|
g2g2 g3 a|gfga g4 |g2a2 gafg|efde ^c2A2|
f2e2 defg|a2g2 f4 |c2c2 c3 d|cdBc A2F2|
f2e2 defg|a2g2 f3 g|g3 a a3 g|fge2 d4 :|
X:2
T:Petit Branle
S:http://www.fourwinds.demon.nl/branles.htm
Z:Jack Campin 2002
M:C|
L:1/8
K:D Dorian
d2a2 f4 |g4 a4 |d2e2 f2ef|gafg e2d2:|
d3 e fga2|d3 e ^c2A2|d3 e fga2|d8 :|
d2e2 ^f2d2|d2e2 ^f2d2|a3 g =fge2|d8 :|
X:3
T:Petit Branle
S:http://www.fourwinds.demon.nl/branles.htm
Z:Jack Campin 2002
M:C|
L:1/8
K:D Dorian
dcde defd|e6 dc| BcAB ^G3 A|[1 A8 :|\
[2 A6 ||
de|f3 g fga2|f3 g f2c2| fga2 a2g2|[1 f6 :|\
[2 f8 ||
f2f2 e2e2|d2d2 c4 |_B2B2 A2A2| G3F F4 |
F2G2 A3 A|GA_Bc A3c | defg a2d2| ^c3d d4:|
X:4
T:Petit Branle
S:http://www.fourwinds.demon.nl/branles.htm
Z:Jack Campin 2002
M:C|
L:1/8
K:D
d2cB A2d2|cdef d2d2|d2cB A2d2|cdef d4:|
d2ef g2f2|e2d2 e2cd|e2e2 e2cd|edef e4 |
ddcB c4 |ddcB c3 B|ABcd e2f2|e3 d d4:|
X:5
T:Petit Branle
S:http://www.fourwinds.demon.nl/branles.htm
Z:Jack Campin 2002
M:C|
L:1/8
K:D
fg|a2a2 a2b2|a3 gf2e2|d2A2 defg|e6 :|
fg|a2d2 agfe|d6 cd|e2A2 edcB|A6 Bc|
d3 e f3 g|a6 ag|fef2 e3 d|d6 :|
X:6
T:Petit Brande
S:http://www.fourwinds.demon.nl/branles.htm
Z:Jack Campin 2002
M:C|
L:1/8
K:C
e3 d c2g2|efg2 e2c2|e3 d c2g2|efg2 e4:|
c2c2 d2d2|e3d/e/ f4 |e3 d c2B2|cdef g4 |
GABc d2d2|e3d/e/ f3 g|a2g2 fge2|d3 c c4:|
X:7
T:Petit Branle
S:http://www.fourwinds.demon.nl/branles.htm
Z:Jack Campin 2002
M:C|
L:1/8
K:C
c2c2 B2g2|a2gf e3 f| g2fe d2c2:|
cdef g4 |agab c'2b2|[1 a4 g4 :|\
[2 a4 g2 ||
ef|g2g2 g2ef|gfga g4 |abc'2 b2a2| g3f e2cd|
e2e2 e2cd|edef e2cd|efg2 f2e2|[1 d4 c2 :|\
[2 d4 c4 |]
X:8
T:Petit Branle
S:http://www.fourwinds.demon.nl/branles.htm
Z:Jack Campin 2002
M:C|
L:1/8
K:G
g2|g2fe d2g2|g2fe dcB2|edef gfga|[1 gab2 a2 :|\
[2 gab2 a4 ||
B3 c d2d2|e4 d2d2|B3 c d2d2|[1 e4 d4 :|\
[2 e4 d2 ||
ga|b2b2 a2g2|agfe d4 |e3 f g3 a| bab2 a2ga|
b2b2 a2g2|agfe d4 |e3 f gab2|[1 a4 g2 :|\
[2 a4 g4 |]
X:9
T:Petit Branle
S:http://www.fourwinds.demon.nl/branles.htm
Z:Jack Campin 2002
M:C|
L:1/8
K:G
d2dc Bcde|decd B2G2|c2c2 cded|[1 c8 :|\
[2 c6 ||
cd|e2e2 efg2|d4 d4 |Bcde c2B2| abga f2d2|
e2e2 efg2|d4 d4 |Bcde cdB2|[1 A3 G G2 :|\
[2 A3 G G4 |]
X:10
T:Petit Branle
S:http://www.fourwinds.demon.nl/branles.htm
Z:Jack Campin 2002
M:C|
L:1/8
K:D Dorian
d2a2 a2a2|g3a f4 |g2a2 defg |e3d d4:|
d2e2 f2f2|e3f g2g2|f2e2 d2a2|^g3a a4 |
d2e2 f2f2|e3f g2g2|a3 g f2f2| e3d d4:|