X:1
T:The Royal Edinr. Volunteers Short Troop
Z:Jack Campin: "Embro, Embro", transcription (c) 2001
F:16army/abc/SchShTrp.abc
N:most respectfully inscribed to the Right Honorable Sir J. Stirling, Bart.
N:Lord Provost and Lord Lieutenant of Edinburgh
B:Glen.347(38), one of a collection of marches in sheet music form
C:J.G.C. Schetky
N:piano score in C, fife one in D
M:C|
L:1/4
V:1 up
V:2 merge down
K:D
P:Slow % [Q:1/2=60]
V:1 a2 g2|f2 b2|a2 gf|HTe4|f2 ^g2|a2 b2|c'2 b2|Ta4||
V:2 f2 e2|d2 g2|f2 ed| HA4|d2  B2|c2 e2|a2  e2| A4||
%
P:Moderato % [Q:1/2=100]
V:1 x2      |x4  |x4  |x4  | Hx2 x2      |x4  |x4     |x4  | xxx Hz|
V:2 z/A/B/c/|dAfd|afdf|afdf|HTe2 z/A/B/c/|dfAd|FAda/g/|fafd|TA3  Hz|
%
P:Andante % [Q:1/2=90]
V:1 f4|Te4|^g4|Ta4||
V:2 d4| A4| B4| A4||
%
P:Allegretto % [Q:1/8=120]
V:1 [M:3/8] [L:1/16]  x x x|x2x2x2|x2x2x2|x2x2x2|x2x2x2|x2x2x2|x2x2x2|x2x2x2|xxx :|
V:2 [M:3/8] [L:1/16] .e.f.g|a2a2f2|d2defd|e2efge|f2defg|a2a2f2|d2fafd|e2gedc|d3  :|
%
V:1                   efg  |a2a2f2|b2baba|g2g2e2|a2agag|f2f2g2|e2e2f2|d2edef|d3  y:|
V:2                   Ade  |f2f2d2|g2gfgf|e2e2A2|f2fefe|d2d2e2|A2a2d2|F2A2A2|F3  y:|
%
V:1                   efg  |a2f2f2|a2f2f2|e2edeg|f2defg|a2f2a2|a2f2a2|e2edef|d3agf|
V:2                   Ade  |f2d2d2|f2d2d2|A2G2A2|d4  z2|f2d2f2|f2d2f2|A2A2A2|F3fed|
%
V:1                         e2edeg|f2dfaf|e2edef|d3baf |e2edeg|f2dfaf|e2edef|d3  y:|
V:2                         A2A2A2|d4  z2|A2A2A2|F4 z2 |A2A2A2|d4  z2|A2A2A2|F3  y:|
%
P:Andante % [Q:1/2=90]
V:1 [M:C|] [L:1/1] Ta2|Tg2|Tf2|Te2|Td2|]
V:2 [M:C|] [L:1/1]  f2| e2| d2| A2| d2|]